병사 증가량
;-------------------------------------------------
;ARG:0番の勢力の徴兵処理
;-------------------------------------------------
@COUNTRY_ADD_SOLDIER(ARG:0)
#DIM LCOUNT
#DIM 歌唱パワー
#DIM 政治パワー
#DIM 補正
#DIM 経済力
#DIM 兵数
#DIM 増加量
#DIM 最大増加量
#DIM 人気所持者数
#DIM 難易度補正
#DIM 防衛振り分け表示
#DIM 防衛振り分け数
#DIM 連邦ナンバー
#DIM 連邦構成国, MAX_COUNTRY

;(従属国パッチ)連邦ナンバー・連邦構成国を検索
FOR LOCAL:0, 0, MAX_COUNTRY
	FOR LOCAL:1, 0, MAX_COUNTRY
		IF TREATY_UNI_COUNTRY:(LOCAL:0):(LOCAL:1):0 == CFLAG:MASTER:所属 || TREATY_UNI_COUNTRY:(LOCAL:0):(LOCAL:1):1 == CFLAG:MASTER:所属
			連邦ナンバー = LOCAL:0
			連邦構成国:(CFLAG:MASTER:所属) = 1
			BREAK
		ENDIF
	NEXT
NEXT

FOR LOCAL:0, 0, MAX_COUNTRY
	IF TREATY_UNI_COUNTRY:連邦ナンバー:(LOCAL:0):0 > 0
		連邦構成国:(TREATY_UNI_COUNTRY:連邦ナンバー:(LOCAL:0):0) = 1
	ELSEIF TREATY_UNI_COUNTRY:連邦ナンバー:(LOCAL:0):1 > 0
		連邦構成国:(TREATY_UNI_COUNTRY:連邦ナンバー:(LOCAL:0):1) = 1
	ENDIF
NEXT
;増加する兵数は経済規模×0.5(警邏・歌唱などによる補正あり)
;最大兵数は経済規模×10

;士官が部隊に所属しているかどうかのリストを作成

;歌唱パワー・政治パワーを取得
政治パワー = 0
歌唱パワー = 0
人気所持者数 = 0
FOR LOCAL:0, 0, CHARANUM
	IF CFLAG:(LOCAL:0):所属 == ARG:0 && TMP_IS_FREE:(LOCAL:0):0 == 0
		政治パワー += ABL_POWER((ABL:(LOCAL:0):政治 + ABL:(LOCAL:0):武闘 / 4), LOCAL:0)
		歌唱パワー += ABL_POWER(ABL:(LOCAL:0):歌唱, LOCAL:0)
		SIF TALENT:(LOCAL:0):人気
			人気所持者数 ++
	ENDIF
NEXT
補正 = SQRT(政治パワー) + SQRT(歌唱パワー)
SIF ARG:0 == CFLAG:MASTER:所属 || FLAG:兵数増加追加値 > 0
	補正 += SQRT(FLAG:兵数増加追加値 / 2) * 2

経済力 = GET_SUM_ECONOMY(ARG:0) / 100
兵数 = GET_SUM_SOLDIER(ARG:0)

;増加量は経済力ベースに補正
増加量 = 補正 * 経済力 * 5 / 10000

;政策による補正
SIF COUNTRY_POLICY:(ARG:0) == 政策_徴兵
	TIMES 増加量, 1.50

;人気持ち一人につき5%増加
;100%まで
増加量 += MAX(増加量 * 10 / 100, 1) * MIN(人気所持者数, 10)

IF ARG:0 != CFLAG:MASTER:所属
	難易度補正 = GET_DIFFICULTY_CORRECTION()
	SIF 難易度補正 > 100
		難易度補正 = 100 + (難易度補正 - 100) / 2
	増加量 = 増加量 * 難易度補正 / 100
ENDIF

;経済力の100倍以上は保持できない
最大増加量 = MAX(経済力 * 100 - 兵数, 0)

SELECTCASE 兵数
	CASE IS > 経済力 * 100
		増加量 = 0
	CASE IS > 経済力 * 75
		増加量 = MIN(増加量, 最大増加量) / 8
	CASE IS > 経済力 * 50
		増加量 = MIN(増加量, 最大増加量) / 6
	CASE IS > 経済力 * 25
		増加量 = MIN(増加量, 最大増加量) / 4
	CASE IS > 経済力 * 125 / 10
		増加量 = MIN(増加量, 最大増加量) / 2
	CASEELSE
		増加量 = MIN(増加量, 最大増加量)
ENDSELECT

COUNTRY_SOLDIER:(ARG:0) += 増加量

IF ARG:0 == CFLAG:MASTER:所属
	IF 増加量 == 0
		CALL COLOR_PRINTL(@"徴兵の限界に達しています、これ以上兵を賄うには経済を増やすか、臨時徴兵をする必要があります", カラー_注意)
	ELSE
		PRINTFORMW 我が国の兵数が{増加量}だけ増加しました
	ENDIF
ENDIF

;防衛兵数が最低数を割っている都市があるなら自動配分
防衛振り分け表示 = 0
FOR LOCAL:0, 0, MAX_CITY
	IF CITY_OWNER:(LOCAL:0) == ARG:0 && CITY_SOLDIER:(LOCAL:0) < 500 && COUNTRY_SOLDIER:(ARG:0) > 0
		;敵部隊のいる都市は増減不可
		SIF IS_STAY_ENEMY_UNIT(LOCAL:0) == 1
			CONTINUE
		防衛振り分け数 = MIN(500 - CITY_SOLDIER:(LOCAL:0), COUNTRY_SOLDIER:(ARG:0))
		CITY_SOLDIER:(LOCAL:0) += 防衛振り分け数
		COUNTRY_SOLDIER:(ARG:0) -= 防衛振り分け数
		防衛振り分け表示 = 1
		SIF ARG:0 == CFLAG:MASTER:所属
			PRINTFORML %GET_CITYNAME(LOCAL:0)%の防衛兵数を{防衛振り分け数}だけ補充しました
	ENDIF
NEXT
IF ARG:0 == CFLAG:MASTER:所属 && 防衛振り分け表示
	WAIT
ENDIF